윈도우에서 gradle로 빌드하시려는 분께 공유드립니다.

맨 위에 공유 해주신거 보고 참고해서 정리한 build.gradle 파일 소스 입니다. 

repositories 에 gradlePluginPortal() 이걸 추가해줘야 합니다.

plugins {
   id 'org.springframework.boot' version '2.5.2'
   id 'io.spring.dependency-management' version '1.0.11.RELEASE'
   id 'java'
   id "com.github.node-gradle.node" version "3.1.0"
}

group = 'me.bingbingpa'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '11'

configurations {
   compileOnly {
      extendsFrom annotationProcessor
   }
}

repositories {
   mavenCentral()
   gradlePluginPortal()
}

dependencies {
   implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
   implementation 'org.springframework.boot:spring-boot-starter-mail'
   implementation 'org.springframework.boot:spring-boot-starter-security'
   implementation 'org.springframework.boot:spring-boot-starter-thymeleaf'
   implementation 'org.springframework.boot:spring-boot-starter-web'
   implementation 'org.springframework.boot:spring-boot-starter-validation'
   implementation 'org.thymeleaf.extras:thymeleaf-extras-springsecurity5'
   compileOnly 'org.projectlombok:lombok'
   developmentOnly 'org.springframework.boot:spring-boot-devtools'
   runtimeOnly 'com.h2database:h2'
   runtimeOnly 'org.postgresql:postgresql'
   annotationProcessor 'org.springframework.boot:spring-boot-configuration-processor'
   annotationProcessor 'org.projectlombok:lombok'

   // npm
   implementation 'com.github.node-gradle:gradle-node-plugin:3.1.0'


   testImplementation 'org.springframework.boot:spring-boot-starter-test'
   testImplementation 'org.springframework.security:spring-security-test'
}

test {
   useJUnitPlatform()
}

node {
   version = '16.3.0'
   download = true
   nodeModulesDir = file("${projectDir}/src/main/resources/static")

}
task copyFrontLib(type: Copy) {
   from "${projectDir}/src/main/resources/static"
   into "${projectDir}/build/resources/main/static/."
}
copyFrontLib.dependsOn npmInstall
compileJava.dependsOn copyFrontLib

좋은 정보 공유해 주셔서 감사합니다.

parksangdonews님께서 그래들 빌드 설정 파일을 PR을 보내주신것도 깃헙에 있으니 참고하시기 바랍니다.

https://github.com/hackrslab/studyolle/blob/master/_build.gradle_