querydsl을 사용할 때 java의 Q클래스와 kotlin의 Q클래스 함께사용 가능한가요??

깃헙계정 입니다! 감사합니다ㅎㅎ
https://github.com/onetaek/linePig

코틀린 파일은 하나도 없고 java 파일만 있는 상태이고, build.gradle 설정만 바꾸었는데 Q클래스가 2개 생성되고있습니다ㅠㅠㅠ 아마 build.gradle의 Q클래스 경로 설정문제인거 같은데 도와주시면 감사하겠습니다ㅠㅠㅠ

아래와 같이 build.gradle에 주석을 달아서 코틀린 도입하며 추가한 build.gradle 코드를 표시하였습니다!!

//--------코틀린 도입을 위한 추가 코드 start-------------

//--------코틀린 도입을 위한 추가 코드 end-------------

plugins {
    id 'org.springframework.boot' version '2.2.2.RELEASE'
    id 'io.spring.dependency-management' version '1.0.8.RELEASE'
    id "com.ewerk.gradle.plugins.querydsl" version "1.0.10"
    id 'java'

    //--------코틀린 도입을 위한 추가 코드 start-------------
    id 'org.jetbrains.kotlin.jvm' version '1.6.21'
    id 'org.jetbrains.kotlin.plugin.jpa' version '1.6.21'
    id 'org.jetbrains.kotlin.plugin.spring' version '1.6.21'
    id 'org.jetbrains.kotlin.kapt' version '1.6.21'
    //--------코틀린 도입을 위한 추가 코드 end-------------
}

group = 'com.maturi'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '8'

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
    developmentOnly
    runtimeClasspath {
        extendsFrom developmentOnly
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-thymeleaf'
    implementation 'nz.net.ultraq.thymeleaf:thymeleaf-layout-dialect'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    developmentOnly("org.springframework.boot:spring-boot-devtools")
    compileOnly 'org.projectlombok:lombok'
    runtimeOnly 'com.h2database:h2'
    runtimeOnly 'org.mariadb.jdbc:mariadb-java-client:2.7.0'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    implementation 'org.modelmapper:modelmapper:2.4.2'
    testCompileOnly 'org.projectlombok:lombok'
    testAnnotationProcessor 'org.projectlombok:lombok'
    implementation 'org.springframework.boot:spring-boot-starter-mail'
    implementation 'com.querydsl:querydsl-jpa'
    compileOnly 'org.projectlombok:lombok'
    runtimeOnly 'com.h2database:h2'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation('org.springframework.boot:spring-boot-starter-test') {
        exclude group: 'org.junit.vintage', module: 'junit-vintage-engine'
    }
    implementation group: 'org.javassist', name: 'javassist', version: '3.15.0-GA'
    implementation group: 'com.google.firebase', name: 'firebase-admin', version: '8.1.0'
    implementation 'org.springframework.social:spring-social-facebook:2.0.3.RELEASE'
    implementation 'org.apache.httpcomponents:httpclient:4.5.2'
    implementation 'com.googlecode.json-simple:json-simple:1.1.1'

    //--------코틀린 도입을 위한 추가 코드 start-------------
    kapt("com.querydsl:querydsl-apt:5.0.0:jpa")
    kapt("org.springframework.boot:spring-boot-configuration-processor")
    //--------코틀린 도입을 위한 추가 코드 end-------------
}

test {
    exclude { '/**/*' }
    useJUnitPlatform()
}

//--------코틀린 도입을 위한 추가 코드 start-------------
compileKotlin {
    kotlinOptions {
        jvmTarget = "8"
    }
}

compileTestKotlin {
    kotlinOptions {
        jvmTarget = "8"
    }
}
//--------코틀린 도입을 위한 추가 코드 end-------------

def querydslDir = "$buildDir/generated/querydsl"
querydsl {
    jpa = true
    querydslSourcesDir = querydslDir
}

sourceSets {
    main.java.srcDir querydslDir
}

configurations {
    querydsl.extendsFrom compileClasspath
}

compileQuerydsl {
    options.annotationProcessorPath = configurations.querydsl
}

clean {
    delete file('src/main/generated')
}

안녕하세요, 백엔드 개발자 취준생님! 😊 보내주신 github 코드로 이것저것 살펴보며 대략적으로 문제를 해결해서 몇 가지 말씀 드려 보도록 하겠습니다.

[1. 왜 QClass가 2개 생겼는가]

결론부터 말씀드리면, QClass가 2개씩 생기던게 맞습니다. 그렇다면 왜 2개씩 생겼는가?

그것은 중첩된 Querydsl 설정 때문입니다.

설정해두셨던 build.gradle 을 살펴보면

• querydsl에 대해 플러그인이 설정되어 있고

• 동시에 querydsl을 직접 import 해서 어노테이션 프로세싱을 해주고 있습니다.

전자는 원래 있던 설정이고, 후자는 Kotlin을 추가해 보시려고 넣으신 설정일 거에요!

문제는 이제 이 각각의 설정이 별도로 적용되어 있다 보니 Querydsl QClass가 2개씩 생기게 되었습니다.

[2. 그렇다면 어떻게 해결해야 하는가]

중첩된 Querydsl 설정 중 하나만 사용하시면 됩니다! 전자의 설정을 그대로 사용하시더라도, Kotlin 으로 작성된 Repository에서 QClass를 가져와 사용하는 것은 전혀 문제가 없을거에요!

다만, 만약 후자의 설정을 사용하신다면, 현재 스프링 부트 버전이 2.x.x 버전이고 스프링 부트 2.6.x 쯔음 부터는 Querydsl 5.0.0 버전을 사용하고 있다보니 스프링 부트 버전 업그레이드가 필요할 수 있습니다.

관련 포스트

• https://lordofkangs.tistory.com/461

• https://lemontia.tistory.com/1089

답변이 도움이 되었으면 좋겠습니다. 감사합니다. 🙏 🙇